Дмитрий Соловьев
ab3a787da5
- новый Spring Cloud Gateway (WebFlux): доменные маршруты /api/pcp-<x>/**
со StripPrefix=2, /api/stations без среза пути, catch-all /api/** → ui-service;
опциональная JWT-валидация на edge (gateway.security.jwt-enabled, по умолчанию off)
- config-repo: pcp-gateway-service.yaml (маршруты) + порт/адрес gateway в реестрах
application-{local,docker-local,dev}
- build: репозитории переведены на mavenCentral (nstart-proxy закомментирован),
включены mavenLocal/gradlePluginPortal; settings: include модуля
- pcp-tgu-ui-service: vite-proxy и nginx.conf свёрнуты на единый /api → gateway
(вместо набора per-service правил)
- deploy: сервис gateway в docker-compose; helm-чарт pcp-gateway-service
- CI: .gitlab/ci/pcp-gateway-service.yml + проводка в .gitlab-ci.yml
70 lines
1.5 KiB
Kotlin
70 lines
1.5 KiB
Kotlin
import org.gradle.api.plugins.JavaPluginExtension
|
|
import org.gradle.jvm.toolchain.JavaLanguageVersion
|
|
|
|
plugins {
|
|
kotlin("jvm") apply false
|
|
kotlin("plugin.spring") apply false
|
|
kotlin("plugin.jpa") apply false
|
|
kotlin("plugin.lombok") apply false
|
|
id("org.springframework.boot") apply false
|
|
id("io.spring.dependency-management") apply false
|
|
//id("org.sonarqube") apply false
|
|
}
|
|
|
|
|
|
allprojects {
|
|
group = "space.nstart.pcp"
|
|
ext.set("kotlinVersion", "2.2.20")
|
|
repositories {
|
|
// maven {
|
|
// url = uri("https://repo.nstart.cloud/repository/maven-proxy/")
|
|
// }
|
|
mavenCentral {
|
|
content {
|
|
includeGroup("org.jacoco")
|
|
includeGroup("org.ow2.asm")
|
|
}
|
|
}
|
|
mavenCentral()
|
|
mavenLocal()
|
|
gradlePluginPortal()
|
|
maven { url = uri("https://jitpack.io") }
|
|
|
|
exclusiveContent {
|
|
forRepository {
|
|
maven("https://repo.osgeo.org/repository/release/")
|
|
}
|
|
filter {
|
|
includeGroup("org.geotools")
|
|
includeGroup("org.geotools.ogc")
|
|
includeGroup("javax.media")
|
|
includeGroup("it.geosolutions.jgridshift")
|
|
}
|
|
}
|
|
|
|
|
|
}
|
|
}
|
|
|
|
subprojects {
|
|
plugins.withId("java") {
|
|
extensions.configure<JavaPluginExtension> {
|
|
toolchain {
|
|
languageVersion = JavaLanguageVersion.of((property("versions.java") as String).toInt())
|
|
}
|
|
}
|
|
}
|
|
|
|
plugins.withId("org.springframework.boot") {
|
|
if (
|
|
path != ":services:pcp-srpring-boot-admin-server" &&
|
|
path != ":services:spring-cloud-config-server"
|
|
) {
|
|
dependencies.add(
|
|
"implementation",
|
|
"de.codecentric:spring-boot-admin-starter-client:${property("versions.spring.boot.admin")}"
|
|
)
|
|
}
|
|
}
|
|
}
|